home *** CD-ROM | disk | FTP | other *** search
/ Amiga Format CD 52 / Amiga Format AFCD52 (Issue 136, May 2000).iso / -serious- / programming / other / dopus412-gpl / program / assembly.asm < prev    next >
Assembly Source File  |  2000-02-28  |  6KB  |  390 lines
  1. ; Directory Opus 4
  2. ; Original GPL release version 4.12
  3. ; Copyright 1993-2000 Jonathan Potter
  4. ; 
  5. ; This program is free software; you can redistribute it and/or
  6. ; modify it under the terms of the GNU General Public License
  7. ; as published by the Free Software Foundation; either version 2
  8. ; of the License, or (at your option) any later version.
  9. ; 
  10. ; This program is distributed in the hope that it will be useful,
  11. ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. ; GNU General Public License for more details.
  14. ; 
  15. ; You should have received a copy of the GNU General Public License
  16. ; along with this program; if not, write to the Free Software
  17. ; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  18. ; 
  19. ; All users of Directory Opus 4 (including versions distributed
  20. ; under the GPL) are entitled to upgrade to the latest version of
  21. ; Directory Opus version 5 at a reduced price. Please see
  22. ; http://www.gpsoft.com.au for more information.
  23. ; 
  24. ; The release of Directory Opus 4 under the GPL in NO WAY affects
  25. ; the existing commercial status of Directory Opus 5.
  26.  
  27. *    include "exec/types.i"
  28.     include "devices/inputevent.i"
  29.  
  30. *STRUCTURE RLEinfo,0
  31. *    APTR rle_sourceptr
  32. *    APTR rle_destplanes
  33. *    WORD rle_imagebpr
  34. *    WORD rle_imageheight
  35. *    WORD rle_imagedepth
  36. *    WORD rle_destbpr
  37. *    WORD rle_destheight
  38. *    WORD rle_destdepth
  39. *    BYTE rle_masking
  40. *    BYTE rle_compression
  41. *    LONG rle_offset
  42. *    LABLE rle_SIZEOF
  43.  
  44. _LVORawDoFmt equ -$20a
  45.  
  46. VIEW_FILE_SIZE       equ 0
  47. VIEW_MAX_LINE_LENGTH equ 4
  48. VIEW_TAB_SIZE        equ 8
  49. VIEW_TEXT_BUFFER     equ 12
  50.  
  51.     XREF _WorkbenchBase
  52.  
  53.     section code
  54.  
  55.     XDEF _lsprintf
  56.  
  57. _lsprintf:
  58.     movem.l a2/a3/a6,-(sp)
  59.     move.l 4*4(sp),a3
  60.     move.l 5*4(sp),a0
  61.     lea.l 6*4(sp),a1
  62.     lea.l stuffChar(pc),a2
  63.     move.l 4,a6
  64.     jsr _LVORawDoFmt(a6)
  65.     movem.l (sp)+,a2/a3/a6
  66.     rts
  67.  
  68. stuffChar:
  69.     move.b d0,(a3)+
  70.     rts
  71.  
  72.     XDEF _countlines
  73.  
  74. _countlines:
  75.     movem.l d2-d5/a2,-(sp) ; save registers
  76.  
  77.     move.l VIEW_FILE_SIZE(a0),d1
  78.     move.l VIEW_MAX_LINE_LENGTH(a0),d2
  79.     move.l VIEW_TEXT_BUFFER(a0),a0
  80.  
  81. * D1 = viewsize
  82. * D2 = maximum line length
  83. * A0 = buffer
  84. * ---
  85. * D0 = number of lines
  86. * D3 = number of characters counted
  87. * D5 = earliest position to wordwrap from
  88. * A1 = last white space character (for wordwrap)
  89.  
  90.     moveq #0,d0
  91.     moveq #0,d3
  92.     move.l d2,d5
  93.     sub.l #10,d5
  94.     move.l #0,a1
  95. loop:
  96.     addq #1,d3
  97.     cmp.l d2,d3
  98.     bne skip1
  99.     cmp.l #0,a1
  100.     beq nolastspace
  101.     move.l a0,a2    
  102.     sub.l a1,a2
  103.     cmp.l d5,a2
  104.     bge nolastspace
  105.     add.l a2,d1
  106.     move.l a1,a0
  107. nolastspace:
  108.     move.b #10,(a0)
  109.     addq #1,d0
  110.     moveq #0,d3
  111.     sub.l a1,a1
  112.     bra skip3
  113. skip1:
  114.     cmpi.b #10,(a0)
  115.     bne skip2
  116.     sub.l a1,a1
  117.     addq #1,d0
  118.     moveq #0,d3
  119.     bra skip3
  120. skip2:
  121.     cmpi.b #9,(a0)
  122.     bne skip3
  123.     move.b #32,(a0)
  124. skip3:
  125.     cmpi.b #32,(a0)
  126.     bne notspace
  127.     move.l a0,a1
  128. notspace:
  129.     subq.l #1,d1
  130.     cmpi.l #0,d1
  131.     beq endcountlines
  132.     addq.l #1,a0
  133.     bra loop
  134. endcountlines:
  135.     cmpi.b #10,(a0)
  136.     beq lastlf
  137.     addq #1,d0
  138. lastlf:
  139.     movem.l (sp)+,d2-d5/a2
  140.     rts
  141.  
  142.     XDEF _smartcountlines
  143.  
  144. _smartcountlines:
  145.     movem.l d2-d7/a2,-(sp)
  146.  
  147.     move.l VIEW_FILE_SIZE(a0),d1
  148.     move.l d1,d7
  149.     move.l VIEW_MAX_LINE_LENGTH(a0),d2
  150.     move.l VIEW_TEXT_BUFFER(a0),a0
  151.  
  152.     moveq #0,d0
  153.     moveq #0,d3
  154.     moveq #0,d4
  155.     move.l d2,d5
  156.     sub.l #10,d5
  157.     moveq #0,d6
  158.     move.l #0,a1
  159. aloop:
  160.     addq #1,d3
  161.     cmp.l d2,d3
  162.     bne askip1
  163.     cmp.l #0,a1
  164.     beq nolastspace1
  165.     move.l a0,a2    
  166.     sub.l a1,a2
  167.     cmp.l d5,a2
  168.     bge nolastspace1
  169.     add.l a2,d1
  170.     move.l a1,a0
  171. nolastspace1:
  172.     move.b #10,(a0)
  173.     sub.l a1,a1
  174.     addq #1,d0
  175.     moveq #0,d3
  176.     bra askip2
  177. askip1:
  178.     cmpi.b #-33,(a0)
  179.     blt aokay
  180.     cmpi.b #-1,(a0)
  181.     ble aishex
  182.     cmpi.b #9,(a0)
  183.     blt aishex
  184.     cmpi.b #14,(a0)
  185.     blt aokay
  186.     cmpi.b #32,(a0)
  187.     blt aishex
  188.     cmpi.b #128,(a0)
  189.     blt aokay
  190.     cmpi.b #160,(a0)
  191.     bge aokay
  192. aishex:
  193.     cmpi.l #6,d7
  194.     blt nomorecheck
  195.     addq #1,d4
  196.     cmpi.l #6,d4
  197.     bge nomorecheck
  198.     cmpi.b #27,(a0)
  199.     bne aokay1
  200.     moveq #1,d6
  201.     bra aokay1
  202. nomorecheck:
  203.     move.l #-1,d0
  204.     movem.l (sp)+,d2-d7/a2
  205.     rts
  206. aokay:
  207.     moveq #0,d4
  208.     cmpi.b #1,d6
  209.     bne aokay1
  210.     cmpi.b #'[',(a0)
  211.     beq isansi
  212.     moveq #0,d6
  213.     bra aokay1
  214. isansi:
  215.     move.l #-2,d0
  216.     movem.l (sp)+,d2-d7/a2
  217.     rts
  218. aokay1:
  219.     cmpi.b #10,(a0)
  220.     bne askip2
  221.     sub.l a1,a1
  222.     addq #1,d0
  223.     moveq #0,d3
  224. askip2:
  225.     cmpi.b #32,(a0)
  226.     bne notspace1
  227.     move.l a0,a1
  228. notspace1:
  229.     subq.l #1,d1
  230.     cmpi.l #0,d1
  231.     beq endsmartcount
  232.     addq.l #1,a0
  233.     bra aloop
  234. endsmartcount:
  235.     cmpi.b #10,(a0)
  236.     beq lastlf1
  237.     addq #1,d0
  238. lastlf1:
  239.     movem.l (sp)+,d2-d7/a2
  240.     rts
  241.  
  242.     XDEF _ansicountlines
  243.  
  244. tabsize:
  245.     dc.l 0
  246.  
  247. _ansicountlines:
  248.     movem.l d2-d7/a2,-(sp)
  249.  
  250.     move.l VIEW_TAB_SIZE(a0),d0
  251.     move.l d0,tabsize
  252.     move.l VIEW_FILE_SIZE(a0),d1
  253.     move.l VIEW_MAX_LINE_LENGTH(a0),d2
  254.     move.l VIEW_TEXT_BUFFER(a0),a0
  255.  
  256.     moveq #0,d0
  257.     moveq #0,d3
  258.     move.l d2,d5
  259.     sub.l #10,d5
  260.     moveq #0,d6
  261.     move.l tabsize,d7
  262.     move.l #0,a1
  263.  
  264. nloop:
  265.     cmpi.b #32,(a0)
  266.     bge notillegal
  267.     cmpi.b #0,(a0)
  268.     blt notillegal
  269.     cmpi.b #9,(a0)
  270.     beq notillegal
  271.     cmpi.b #10,(a0)
  272.     beq notillegal
  273.     cmpi.b #27,(a0)
  274.     beq notillegal
  275.  
  276.     move.b #' ',(a0)
  277.     bra nottab
  278.  
  279. notillegal:
  280.     cmpi.b #27,(a0)
  281.     bne notescape
  282.     moveq #1,d6
  283.     bra nnotspace
  284. notescape:
  285.     cmpi.b #1,d6
  286.     bne notansi
  287.     cmpi.b #';',(a0)
  288.     beq nnotspace
  289.     cmpi.b #'[',(a0)
  290.     beq nnotspace
  291.     cmpi.b #'0',(a0)
  292.     blt endansi
  293.     cmpi.b #'9',(a0)
  294.     ble nnotspace
  295. endansi:
  296.     moveq #0,d6
  297.     bra nnotspace
  298.  
  299. notansi:
  300.     cmpi.b #9,(a0)
  301.     bne nottab
  302.     add.l d7,d3
  303.     move.l tabsize,d7
  304.     bra notnexttab
  305. nottab:
  306.     addq #1,d3
  307.     subq #1,d7
  308.     cmpi.b #0,d7
  309.     bgt notnexttab
  310.     move.l tabsize,d7
  311. notnexttab:
  312.     cmp.l d2,d3
  313.     blt nskip1
  314.     cmp.l #0,a1
  315.     beq nnolastspace
  316.     move.l a0,a2    
  317.     sub.l a1,a2
  318.     cmp.l d5,a2
  319.     bge nnolastspace
  320.     add.l a2,d1
  321.     move.l a1,a0
  322. nnolastspace:
  323.     move.b #10,(a0)
  324.     addq #1,d0
  325.     moveq #0,d3
  326.     moveq #0,d6
  327.     move.l tabsize,d7
  328.     sub.l a1,a1
  329.     bra nskip2
  330. nskip1:
  331.     cmpi.b #10,(a0)
  332.     bne nskip2
  333.     sub.l a1,a1
  334.     addq #1,d0
  335.     moveq #0,d3
  336.     moveq #0,d6
  337.     move.l tabsize,d7
  338. nskip2:
  339.     cmpi.b #32,(a0)
  340.     beq isspace
  341.     cmpi.b #9,(a0)
  342.     bne nnotspace
  343. isspace:
  344.     move.l a0,a1
  345. nnotspace:
  346.     addq.l #1,a0
  347.     subq.l #1,d1
  348.     cmpi.l #0,d1
  349.     bgt nloop
  350.     movem.l (sp)+,d2-d7/a2
  351.     rts
  352.  
  353.     XDEF _removetabs
  354.  
  355. _removetabs:
  356.     move.l VIEW_FILE_SIZE(a0),d1
  357.     move.l VIEW_TEXT_BUFFER(a0),a0
  358.  
  359.     moveq #0,d0
  360. rloop:
  361.     cmpi.b #9,(a0)
  362.     bne rskip
  363.     move.b #' ',(a0)
  364. rskip:
  365.     addq.l #1,a0
  366.     subq.l #1,d1
  367.     cmpi.l #0,d1
  368.     bgt rloop
  369.     rts
  370.  
  371.     XDEF _filteroff
  372.  
  373. _filteroff:
  374.     btst.b #1,$bfe001
  375.     bne alreadyon
  376.     bset.b #1,$bfe001
  377.     moveq.l #1,d0
  378.     rts
  379. alreadyon:
  380.     moveq.l #0,d0
  381.     rts
  382.  
  383.     XDEF _filteron
  384.  
  385. _filteron:
  386.     bclr.b #1,$bfe001
  387.     rts
  388.  
  389.     end
  390.